# ODP::Category - An ODP public page parsing class (Version 0.01)
# Copyright (C) 2002 - 2004 Richard P. Fuller <rpfuller@rpfuller.org>

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

package ODP::Category;

use strict;
use LWP::Simple;
use URI::Escape;
use ODP::Site;
use ODP::Search;



# new - Initialises a new ODP::Category object
# Parameters: category
# Returns: ODP::Category object
sub new ($)
{
   my $object = {};
   if (!defined $_[1])
   {
      die 'No category supplied.';
   }
   $object->{'category'} = normalise($_[1]);

   return bless $object;
}



# fetch - Fetches the public page and stores the source in the object
# Parameters: <none>
# Returns: <none>
sub fetch
{
   my $self = shift;
   
   if (!$self->{'category'})
   {
      # Make a fake page for Top/
      foreach my $cat ('Arts','Business','Computers','Games','Health','Home','Kids_and_Teens','News','Recreation','Reference','Regional','Science','Shopping','Society','Sports','World')
      {
         $self->{'content'} .= "<li><a href=\"/$cat\"><b>$cat</b></a>\n &nbsp;<i>(0)</i>";
      }
      
      return;
   }
   
   $self->{'content'} = LWP::Simple::get("http://dmoz.org/$self->{'category'}");
}


# convert - Converts the character set of the entire category
# Parameters: from charset, to charset
# Returns: <none>
sub convert($$)
{
   my $self = shift;
   my ($from, $to) = @_;
   
   if (!$self->{'content'})
   {
      $self->fetch;
   }
   
   require Text::Iconv;
   Text::Iconv->import();
   
   my $converter = Text::Iconv->new($from, $to);
   $self->{'content'} = $converter->convert($self->{'content'});
}



# exists - Returns whether or not a category exists
# Parameters: <none>
# Returns: Whether or not the category exists (boolean)
sub exists
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }
   
   if (!$self->{'content'})
   {
      return 0;
   }
   else
   {
      return 1;
   }
}


# subcats - Returns an array of subcategory objects
# Parameters: <none>
# Returns: array of subcategories (array of ODP::Category objects)
sub subcats
{
   my $self = shift;
   
   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};
   my $page2 = $page;

   my @subcats = ();

   while ($page =~ s/<li><a href="\/([^\"]+)"><b>([^\<]+)<\/b><\/a>\n &nbsp;<i>\([^\)]+\)<\/i>//)
   {
      my ($path,$cat)=($1,$2);
      push @subcats, new ODP::Category($self->{'category'}."/".$cat);
   }

   while ($page2 =~ s/<li><a href="\/([^\"]+)"><b>([^\<]+)<\/b><\/a>&nbsp;\([^\)]+\)//)
   {
      my ($path,$cat)=($1,$2);
      push @subcats, new ODP::Category($self->{'category'}."/".$cat);
   }
   
   while ($page2 =~ s/<a href=\"\/([^\"]+)\"><b>(.)<\/b><\/a>//)
   {
      my ($path,$cat)=($1,$2);
      if ($path eq "$self->{'category'}/$cat/") # If this is a real subcategory, not an alphabar sideways link
      {
         push @subcats, new ODP::Category($self->{'category'}."/".$cat);
      }
           
   }

   return @subcats;
}



# subcats_plain - Returns an array of subcategories
# Parameters: <none>
# Returns: array of subcategories (array of strings)
sub subcats_plain
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};
   my $page2 = $page;

   my @subcats = ();

   while ($page =~ s/<li><a href="\/([^\"]+)"><b>([^\<]+)<\/b><\/a>\n &nbsp;<i>\([^\)]+\)<\/i>//)
   {
      my ($path,$cat)=($1,$2);
      push @subcats, normalise($cat);
   }
   
   while ($page2 =~ s/<li><a href="\/([^\"]+)"><b>([^\<]+)<\/b><\/a>&nbsp;\([^\)]+\)//)
   {
      my ($path,$cat)=($1,$2);
      push @subcats, normalise($cat);
   }

   while ($page2 =~ s/<a href=\"\/([^\"]+)\"><b>(.)<\/b><\/a>//)
   {
      my ($path,$cat)=($1,$2);
      if ($path eq "$self->{'category'}/$cat/") # If this is a real subcategory, not an alphabar sideways link
      {
         push @subcats, normalise($cat);
      }
   }
   return @subcats;
}



# newsgroups - Returns an array containing a list of newsgroups
# Parameters: <none>
# Returns: array of newsgroups (array of strings)
sub newsgroups
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};

   my @newsgroups = ();

   while ($page =~ s/<li>Usenet ([^ ]+) - <small><a href="news:([^ ]+)">news:<\/a> - <a href="http:\/\/groups\.google\.com\/groups\?group=([^"]+)">Google Groups<\/a><\/small>//)
   {
      push @newsgroups, $1;
   }

   return @newsgroups;
}



# encoding - Returns the encoding used for the category (text)
# Parameters: <none>
# Returns: encoding (string)
sub encoding
{
   my $self = shift;
   
   if (!$self->{'content'})
   {
      $self->fetch();

      if ($self->{'content'} =~ m|<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=([^"]+)">|i)
      {
         return $1;
      }
      else
      {
         return '';
      }
   }
}

# altlangs - Returns an array of altlangs (category objects)
# Parameters: <none>
# Returns: array of altlangs (array of ODP::Category objects)
sub altlangs
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};

   my @altlangs = ();

   if ($page =~ /<\/td><\/tr><tr><td valign=top><ul><table cellpadding=0 cellspacing=0>\n<tr><td><li>(.*?)<\/tr><\/table>/s)
   {
      my $p1=$1;
      while ($p1 =~ s/<a href=\"\/([^\"]+)\">.*?<\/a>//)
      {
         my $z=$1;
         $z =~ s/\/$//g;
         push @altlangs, new ODP::Category(uri_unescape($z));
      }
   }
   elsif ($page =~ /<\/td>(?:<\/tr><tr>)?<td valign=top><table cellpadding=0 cellspacing=0>\n<tr><td>(.*?)<\/table><\/td><\/tr><\/table>/s)
   {
      my $p1=$1;
      while ($p1 =~ s/<a href=\"\/([^\"]+)\">.*?<\/a>//)
      {
         my $z=$1;
         $z =~ s/\/$//g;
         push @altlangs, new ODP::Category(uri_unescape($z));
      }
   }

   return @altlangs;
}



# lastupdated - Returns the date a page was last updated in raw format
# Parameters: <none>
# Returns: page last updated date in raw format (string)
sub lastupdated
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};

   my $lastupdated;

   if ($page =~ /<center>\n<font color="#666666" size="-1" face="sans-serif, Arial, Helvetica">\n(.*)\n- <a href="\/editors\/editcat\.cgi\?cat=[^\"]+">edit<\/a>\n<\/font>\n<\/center>/)
   {
      $lastupdated = $1;
   }
   
   return $lastupdated;
}



# sitecount - Returns the number of sites reported in the category
# Parameters: <none>
# Returns: The number of sites in the category, according to the public page (integer)
sub sitecount
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};

   my $sitecount;

   if ($page =~ /<table align=center width="100%" cellpadding=0 cellspacing=0><tr><td align=left valign=top><font size="\+1"><b>.*?<\/b><\/font> &nbsp;<i>\(([^\)]+)\)<\/i>/s)
   {
      $sitecount = $1;
   }
   
   $sitecount =~ s/,//g;

   if ($sitecount !~ /^\d*$/)
   {
      die('Invalid site count detected.');
   }

   return $sitecount;
}



# sites - Returns an array of ODP::Site objects of sites in the category
# Parameters: <none>
# Returns: An array of ODP::Site objects of sites in the category (note 0 is the first site)
sub sites
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }
   
   my $page = $self->{'content'};
   
   my @sites;

   # Handle cooled sites
   # (can never have a media date showing)

   while ($page =~ s/\n<li><a href="([^\"]+)"><b>([^<]+)<\/b><\/a> <img src="\/img\/star\.gif" width=15 height=16 alt=""> &nbsp; \n(.*)//)
   {
      my ($url, $title, $desc) = ($1, $2, $3);
      
      my $agetag;

      if ($desc =~ s/^ <small>\[ ([^\]]+)\]<\/small>//)
      {
         $agetag=substr($1,0,length($1)-1);
      }
      
      $desc =~ s/^ \- //;
      push @sites, new ODP::Site($url, $title, $desc, '', 1, $self->{'category'},$agetag);
   }

   # Handle non-cooled sites
   while ($page =~ s/\n<li><a href="([^\"]+)">([^<]+)<\/a>(.*)//)
   {
      my ($url, $title, $desc) = ($1, $2, $3);
      my $mediadate;
      my $agetag;

      if ($desc =~ s/^ <small>\[ ([^\]]+)\]<\/small>//)
      {
         $agetag=substr($1,0,length($1)-1);
      }
      
      $desc =~ s/^ \- //;
      if ($desc =~ s/<small>\(([^\)]+)\)<\/small>$//)
      {
         $mediadate = $1;
      }
      
      push @sites, new ODP::Site($url, $title, $desc, $mediadate, 0, $self->{'category'},$agetag);
   }

   return @sites;
}



# search - Returns an ODP::Search object to search the category for a term
# Parameters: search term
# Returns: ODP::Search object
sub search($)
{
   my $self = shift;
   my $term = $_[0];
   return new ODP::Search($term, $self->{'category'}, 1);
}



# normalise - Takes a category and puts it in a standardised /_ format
# Parameters: raw category
# Returns: standardised category
sub normalise ($)
{
   my ($category) = @_;
   $category =~ s/^ //g;
   $category =~ s/ $//g;
   $category =~ s/(?:  )+/ /g;
   $category =~ s/: /\//g;
   $category =~ s/ /_/g;
   $category =~ s/^Top\///;
   $category =~ s/^http:\/\/(?:editors\.)?dmoz\.org\///;
   $category =~ s/^editors\/editcat\.cgi\?cat=//;

   # And we'll take out .. too
   while($category =~ s/\.\.//g){}

   # Clean up leading/trailing slashes
   $category =~ s/^\/+//;
   $category =~ s/\/+$//;

   return $category;
}


# symlinks_hash - Returns a hash of symlinks
# Parameters: <none>
# Returns: hash of symlinks
sub symlinks_hash
{
   my $self = shift;

   if (!$self->{'content'})
   {
      $self->fetch;
   }

   my $page = $self->{'content'};

   my %symlinks = ();
   
   while ($page =~ s/<li><a href="\/([^\"]+)"><b>([^\<]+)<\/b><\/a>@\n &nbsp;<i>\([^\)]+\)<\/i>//)
   {
      my ($path, $cat)=($1,$2);
      $symlinks{normalise($cat)} = normalise($path);
   }

   return %symlinks;
}

1;